steve's blog

Well, after much fiddling, I now have a single Jeenode temperature sensor node broadcasting temperature readings to another Jeenode which displays the readings on its serial port.

You’ll see there is space in the data packet for sending all four Jeenode port values and its battery level (to be worked out later).

Next step is to work on optimising the power usage of the sensor node.

The config is a Jeenode SMD with a Sparkfun TMP102 board attached to Port 1 on the Jeenode.

The sensor node code (Jeenode_temperature_sensor_tmp102_rf102b_v1_2) is:

#include <JeeLib.h>
#include <Ports.h>

//    TMP102 on Jeenode port 1
//      SDA to DIO
//      SCL to AIO
int tmp102Address = 0x48;  // ADD0 to ground on TMP102
PortI2C   myport(1, PortI2C::KHZ100);
DeviceI2C temperature(myport, tmp102Address); 

// RF stuff
#define RF_NODEID 5
#define RF_CHANNEL 111

// this must be added since we're using the watchdog for low-power waiting
// ISR(WDT_vect) { Sleepy::watchdogEvent(); }

// number of millisecs to powerdown and sleep for between reading and sending reading
#define DELAY 30000

//data Structure to be sent, called payload

typedef struct {
      	  int            nodeid;		// sending node ID
          unsigned  long uptime;               // time since node boot
          float          battery;               // Jeenode battery level       
	  float          data_1;
          float          data_2;
          float          data_3;
          float          data_4;
} Payload;
Payload data;

 
void setup() {
  rf12_initialize(RF_NODEID, RF12_868MHZ, RF_CHANNEL);
  Serial.begin(57600);
  Serial.println("Initalising...");
  data.nodeid = RF_NODEID;
}  
  

void loop() {
  while (!rf12_canSend())
    rf12_recvDone();
  
  data.data_1 = getTemperature();
  data.uptime = millis();
  
  Serial.print(data.uptime/1000.0);
  Serial.print("\t");
  Serial.println(data.data_1);
    
  rf12_sendStart(0, &data, sizeof data);
  // rf12_sendWait(2);

  delay(DELAY);
//  rf12_sleep(RF12_SLEEP);
//  Sleepy::loseSomeTime(DELAY);
//  rf12_sleep(RF12_WAKEUP);
}

// Function to get temperature from TMP102 and return it as a float in Celsius
float getTemperature()
{   
  temperature.send();             // go into send mode
  temperature.write(0x00);        //
  temperature.receive();          // grab it
  byte MSB = temperature.read(0); // Whole degrees
  byte LSB = temperature.read(1); // fractional degrees
  temperature.stop();             // done

  int TemperatureSum = ((MSB <<  | LSB) >> 4; //it's a 12bit int, using two's compliment for negative
  float celsius = TemperatureSum*0.0625;
  
  // Serial.print(MSB,BIN);
  // Serial.print(" ");
  // Serial.print(LSB,BIN);
  // Serial.print("\t");
  // Serial.print(TemperatureSum, BIN);
  // Serial.print("\t");
  // Serial.print(celsius);
  // Serial.println();
  
  return celsius;
}

The receiving node code (Jeenode_temperature_receiver_tmp102_rf102b_v1_2) is:

#include <JeeLib.h>

// RF stuff
#define RF_NODEID 1
#define RF_CHANNEL 111

#define BLUE_LED 9

// this must be added since we're using the watchdog for low-power waiting
// ISR(WDT_vect) { Sleepy::watchdogEvent(); }

// number of millisecs to powerdown and sleep for between reading and sending reading
#define DELAY 5000
// receive buffer size
#define BUFFER_SIZE 64

// Payload data structure
typedef struct {
      	  int            nodeid;		// sending node ID
          unsigned  long uptime;                // time since node boot      
          float          battery;               // Jeenode battery level       
	  float          data_1;
          float          data_2;
          float          data_3;
          float          data_4;
} Payload;
Payload data;

 
void setup() {
  rf12_initialize(RF_NODEID, RF12_868MHZ, RF_CHANNEL);
  
  pinMode(BLUE_LED, OUTPUT);
  digitalWrite(BLUE_LED, HIGH);        //off  

  Serial.begin(57600);
  Serial.println("Initalising...");
  // flash the LED to signify booting
  digitalWrite(BLUE_LED, LOW);
  delay(100);
  digitalWrite(BLUE_LED, HIGH);
  delay(150);
  digitalWrite(BLUE_LED, LOW);
  delay(200);
  digitalWrite(BLUE_LED, HIGH);
}  
  

void loop() {
  if (rf12_recvDone()) {
    if (rf12_crc == 0) {
      Serial.print(millis()/1000.0);
      Serial.print("\t");
      Serial.print(rf12_hdr, BIN);
      Serial.print("\t");
      Serial.print(rf12_len);
      Serial.print("\t");
      
      data=*(Payload*) rf12_data;
      Serial.print(data.nodeid);
      Serial.print("\t");
      Serial.print(data.uptime/1000.0);
      Serial.print("\t");
      Serial.print(data.data_1);
      Serial.println();
      
      // quick double flash on receipt of packet
      digitalWrite(BLUE_LED, LOW);
      delay(75);
      digitalWrite(BLUE_LED, HIGH);
      delay(75);
      digitalWrite(BLUE_LED, LOW);
      delay(75);
      digitalWrite(BLUE_LED, HIGH);
    } 
  }
}